Нужно чтобы в веб-клиенте запускалась только одна обработка на весь экран (а-ля рабочее место сотрудника), т.к. надо скрыть все панели, которые только возможно. Подскажите как сделать. Следующее для веб-клиента не катит:

НовНастройка= Новый НастройкиКлиентскогоПриложения;
НовНастройка.ОтображатьПанелиНавигацииИДействий = Ложь;
НовНастройка.ОтображатьПанельРазделов = Ложь;
ХранилищеСистемныхНастроек.Сохранить("Общее/НастройкиКлиентскогоПриложения",,НовНастройка);

(0) А зачем скрывать? Чтобы не было понятно, что это 1С? Доступ для клиентов делаете?

(1) Нет, не для клиентов, а для своих сотрудников. Просто чтобы было АРМ, состоящее из одной обработки без лишних панелей.

(2) Для такси такой вариант подойдет. В модуле управляемого приложения:

Процедура ПриНачалеРаботыСистемы()
    МойОбщийМодуль.СкрытьПанели();
КонецПроцедуры


В общем серверном модуле МойОбщийМодуль:

Функция СкрытьПанели() Экспорт
    
    // Для примера будем менять настройки пользователя "не глядя" на то, что он себе настроил.
    // Создать пустой объект настроек.
    НастройкиИнтерфейса = Новый НастройкиИнтерфейсаКлиентскогоПриложения;
    
    // С помощью пустого объекта настроек получить настройки состава, установленные в конфигураторе.
    НастройкиСостава = НастройкиИнтерфейса.ПолучитьСостав();
    
    // Очистить настройки состава.
    НастройкиСостава.Верх.Очистить();
    НастройкиСостава.Лево.Очистить();
    НастройкиСостава.Низ.Очистить();
    НастройкиСостава.Право.Очистить();
    
    // Заполнить своими панелями.
    
    ГруппаПанелей = Новый ГруппаНастройкиСоставаИнтерфейсаКлиентскогоПриложения;
    
    ПанельИнструментов = Новый ЭлементНастройкиСоставаИнтерфейсаКлиентскогоПриложения("ПанельФункцийТекущегоРаздела");
    ГруппаПанелей.Добавить(ПанельИнструментов);
    
    ПанельИнструментов = Новый ЭлементНастройкиСоставаИнтерфейсаКлиентскогоПриложения("ПанельИнструментов");
    ГруппаПанелей.Добавить(ПанельИнструментов);
    
    //НастройкиСостава.Верх.Добавить(ГруппаПанелей);
    
    // Загрузить настройки состава в пустой объект настроек.
    НастройкиИнтерфейса.УстановитьСостав(НастройкиСостава);
    
    // Положить объект настроек текущему пользователю в хранилище.
    ХранилищеСистемныхНастроек.Сохранить("Общее/НастройкиИнтерфейсаКлиентскогоПриложения", , НастройкиИнтерфейса);

    // Если же хотим менять настройки, которые установил пользователь себе,
    // тогда нужно прочитать его настройки из хранилища, и метод ПолучитьСостав()
    // вернёт не то, что в конфигураторе, а то, что пользователь установил себе.
    //
    // НастройкиИнтерфейса = ХранилищеСистемныхНастроек.Загрузить("Общее/НастройкиИнтерфейсаКлиентскогоПриложения");
    // НастройкиСостава = НастройкиИнтерфейса.ПолучитьСостав();    
    // ... изменть настройки состава
    // НастройкиИнтерфейса.УстановитьСостав(НастройкиСостава);
    // ХранилищеСистемныхНастроек.Сохранить("Общее/НастройкиИнтерфейсаКлиентскогоПриложения", , НастройкиИнтерфейса);

КонецФункции