СКД

надо объединить одинаковые заголовки?

Процедура ДействияФормыСформировать(Кнопка)
    ЭлементыФормы.Результат.Очистить();

    СкомпоноватьРезультат(ЭлементыФормы.Результат,ДанныеРасшифровки);

    ОбработатьЗаголовки(ЭлементыФормы.Результат);
КонецПроцедуры

// Проверка двух смежных ячеек на идентичночность
Функция ОбъединятьЯчейки(ТабДок, индСтр, индКол)

    Ячейка = ТабДок.Область(индСтр, индКол);
    ЯчейкаСлед = ТабДок.Область(индСтр, индКол+1);
    Если ПустаяСтрока(Ячейка.Текст) Тогда

        Возврат ложь

    ИначеЕсли
        //Проверяем на соответствие заголовка
        СокрЛП(Ячейка.Текст) = СокрЛП(ЯчейкаСлед.Текст)
        // Проверяем на соответствие имени (отсеиваем уже объединенные ячейки)
        и Ячейка.Имя = "R"+индСтр+"C"+индКол Тогда

        Возврат Истина;

    Иначе

        Возврат ложь

    КонецЕсли;

КонецФункции

// Обработка заголовков таблицы
//
// Параметры
//  Табл  - < Тип.ТабличныйДокумент> - Табличный документ формы
Процедура ОбработатьЗаголовки(ТабДок)

    ОбъединяемаяОбласть = Неопределено;

    //Для оптимизации здесь нужно будет ограничить высоту таблицы
    Для индСтр=1 По ТабДок.ВысотаТаблицы Цикл

        НачальнаяКолонка = 0;
        Для индКол=1 По ТабДок.ШиринаТаблицы Цикл

            // определяем начало объединения
            Если ОбъединятьЯчейки(ТабДок, индСтр, индКол) Тогда

                Если не НачальнаяКолонка Тогда

                    НачальнаяКолонка = индКол;

                КонецЕсли;

            ИначеЕсли НачальнаяКолонка Тогда
                // завершаем объединение

                ТекстЗаголовка = ТабДок.Область(индСтр, индКол).Текст;
                ОбъединяемаяОбласть = ТабДок.Область(индСтр, НачальнаяКолонка, индСтр, индКол);
                ОбъединяемаяОбласть.Объединить();
                ОбъединяемаяОбласть.ГоризонтальноеПоложение = ГоризонтальноеПоложение.Центр;
                ОбъединяемаяОбласть.Текст = ТекстЗаголовка;
                НачальнаяКолонка = 0;

            Иначе

                НачальнаяКолонка = 0;

            КонецЕсли;

        КонецЦикла;

        // Если нашли в строке области для объединения, то прекращаем дальнейшие поиски
        Если не ОбъединяемаяОбласть = Неопределено Тогда

            возврат;

        КонецЕсли;

    КонецЦикла;

КонецПроцедуры